Có phải các bạn đang tìm kiếm một giải pháp hoặc công thức Excel để đếm số ký tự trong một ô? Nếu câu trả lời là yes, thì chúc mừng bạn đã tìm đúng trang rồi đấy. Bài hướng dẫn dưới đây sẽ dạy bạn cách sử dụng hàm LEN để đếm số ký tự trong ô, dù bạn có tính hay không tính khoảng trắng giữa các từ.
Hàm LEN là gì?
Trong tất cả các hàm Excel có lẽ hàm LEN được coi là hàm dễ và đơn giản nhất. Tên hàm cũng rất dễ nhớ, không có gì ngoài ba ký tự đầu của từ “length”. Và đó cũng chính là tác dụng thật sự của hàm LEN trả về chiều dài của chuỗi ký tự, hay chiều dài của một ô.
Nói cách khác, bạn có thể sử dụng hàm LEN trong Excel để đếm tất cả ký tự trong một ô, bao gồm chữ cái, chữ số, ký tự đặc biệt, và tất cả khoảng trống (trắng).
Trong bài hướng dẫn dưới đây chúng ta sẽ tìm hiểu nhanh cú pháp hàm LEN trước, sau đó sẽ tìm hiểu kỹ một vài mẫu công thức để đếm số ký tự trong Excel các bạn nhé.
Tác dụng của hàm LEN trong Excel
Hàm LEN trong Excel đếm tất cả ký tự trong một ô, rồi trả về chiều dài chuỗi.
Cú pháp hàm LEN
=LEN(text)Text chính là chuỗi ký tự nơi mà bạn muốn đếm số ký tự hoặc ô trong Excel
Bạn sẽ tìm thấy một vài công thức đơn giản bên dưới nhằm giúp bạn hiểu sơ qua công dụng của hàm LEN trong Excel.
=LEN(135) – trả về 3, bởi vì 3 chữ số được nhập vào câu lệnh text.
=LEN("NAMXUYEN") – trả về 8 bởi vì từ NAMXUYEN có 8 chữ cái. Giống như bất cứ công thức Excel nào khác, hàm LEN bắt buộc bạn phải đặt chuỗi ký tự bên trong dấu ngoặc kép, và đương nhiên rồi dấu ngoặc kép này sẽ không được đếm.
Khi sử dụng công thức LEN, bạn có thể cần phải nhập tham chiếu ô thay vì chữ số hay chuỗi ký tự , để đếm số ký tự trong một ô cụ thể hay một dải ô.
Ví dụ
Để tính được chiều dài chuỗi ký tự trong ô A5, bạn sẽ dùng công thức này:
=LEN(A5)
Dưới đây sẽ có thêm nhiều ví dụ có lời giải thích chi tiết và cả ảnh chụp minh họa cho các bạn dễ hình dùng.
Cách đếm tất cả các ký tự trong một ô ( bao gồm cả khoảng trắng)
Như đã nói lúc trước, hàm LEN trong Excel đếm tất cả ký tự trong một ô cụ thể một cách tuyệt đối, bao gồm tất cả khoảng trống hay thụt đầu dòng, thụt cuối dòng, và cả khoảng trống giữa các từ.
Ví dụ, để tính chiều dài của ô A3, bạn sử dụng công thức này:
=LEN(A3)
Như được diễn giải trong ảnh chụp màn hình dưới đây, công thức LEN đếm được 31 ký tự, bao gồm các chữ cái và khoảng trống.
Đếm số ký tự trong nhiều ô
Để đếm số ký tự trong nhiều ô, hãy chọn ô có công thức LEN rồi sao chép sang ô khác, ví dụ bằng cách kéo ô vuông nằm dưới góc bên phải .
Ngay khi sao chép công thức, hàm LEN sẽ trả về số ký tự đếm được trong mỗi ô.
Và một lần nữa, hãy lưu ý rằng hàm LEN đếm tất cả mọi thứ một cách tuyệt đối bao gồm chữ cái, chữ số, khoảng trống, dấu phẩy, dấu ngoặc kép, dấu ngoặc đơn, và còn nhiều nữa:
Lưu ý. Khi sao chép một công thức xuống các cột khác, hãy chắc rằng bạn sử dụng tham chiếu ô tương đối chẳng hạn như LEN(A3), hay một tham chiếu hỗn hợp như LEN($A3) chỉ dùng cố định cho cột, nên công thức LEN của bạn sẽ điều chỉnh một cách thích hợp với vị trí mới.
Đếm tất cả ký tự trong nhiều ô
Cách rõ ràng nhất để đếm tất cả ký tự trong vài ô là sử dụng nhiều hàm LEN.
Ví dụ
=LEN(A2)+LEN(A3)+LEN(A4)
Hoặc có thể sử dụng hàm SUM để tính tổng số ký tự được trả về bởi hàm LEN:
=SUM(LEN(A2),LEN(A3),LEN(A4))
Cách nào cũng được, công thức đều đếm số ký tự trong mỗi ô xác định rồi trả về tổng chiều dài chuỗi:
Cách đếm số ký tự không tính khoảng trống dầu dòng và cuối dòng
Khi thao tác với bảng tính lớn thì vấn đề phổ biến chính là khoảng cách đầu dòng và cuối dòng, ví dụ: khoảng trống ở đầu hay ở cuối ký tự. Thong thường chúng ta hầu như không thấy chúng trên bảng tính, nhưng sau khi bạn gặp chúng một vài lần, thì bạn sẽ dễ nhận thấy chúng hơn.
Nếu bạn nghi ngờ có vài khoảng trống vô hình trong các ô thì hàm LEN trong Excel sẽ giúp ích rất nhiều. Hy vọng bạn còn nhớ, nó đếm tất cả khoảng trống trong phép đếm ký tự:
Để tính được chiều dài chuỗi mà không đếm khoảng trống đầu dòng và cuối dòng, hãy nhớ lồng ghép hàm TRIM vào hàm LEN trong Excel:
=LEN(TRIM(A5))
Cách đếm số ký tự trong một ô không tính các khoảng trống
Nếu mục đích của bạn chỉ là đếm số ký tự mà không tính các khoảng trống cho dù đó là khoảng trống đầu dòng, cuối dòng hay giữa các từ, thì bạn sẽ cần một công thức phức tạp hơn:
=LEN(SUBSTITUTE(A5," ",""))
Chúng ta sử dụng hàm SUBSTITUTE thay thế ký tự này với ký tự khác. Trong công thức trên, bạn thay thế khoảng trống (" ") bằng một ký tự rỗng, ví dụ một chuỗi ký tự rỗng (""). Và bởi vì bạn lồng ghép hàm SUBSTITUTE vào hàm LEN nên phép thế thật sự không được thực hiện trong các ô, mà nó chỉ hướng dẫn công thức LEN tính chiều dài chuỗi mà không tính các khoảng trống.
Cách đếm số ký tự trước hay sau một ký tự xác định
Thông thường, bạn cần phải biết chiều dài của một phần nhất định của chuỗi ký tự, thay vì đếm tổng số ký tự trong một ô.
Giả sử, bạn có một danh sách mã hàng hóa như sau:
| Mã Hàng |
| ABCDE-091 |
| BCDJ-082 |
| JKQLF-0091 |
| KLJGH-9001 |
| MNOPQRS-BCD |
Các mã hàng được ngăn cách bởi dấu "-" và tất cả mã hàng hóa hợp lệ đều có chính xác 5 ký tự trong nhóm đầu tiên. Vậy làm thế nào để chúng ta chỉ ra được mã hàng hóa nào là không hợp lệ? Cách giải quyết đơn giản là đếm số ký tự trong nhóm đầu tiên
Công thức áp dụng cho bài toán trên có dạng như sau:
=LEN(LEFT($A2, SEARCH("-", $A2) -1))
Và bây giờ, hãy chia nhỏ công thức ra để bạn có thể hiểu quy luật của nó:
Bạn sử dụng hàm SEARCH để trả về vị trí của dấu gạch ngang đầu tiên ("-") trong ô A2:
SEARCH("-", $A2)
Sau đó, bạn sử dụng hàm LEFT để trả về các ký tự phía bên trái của chuỗi ký tự, rồi lấy kết quả trừ 1 bởi vì bạn không muốn tính luôn dấu gạch ngang:
LEFT($A2, SEARCH("-", $A2) -1)
Và cuối cùng, bạn có hàm LEN để trả về chiều dài của chuỗi đó.
Ngay khi có kết quả, có lẽ bạn muốn thực hiện thêm một bước nữa, là đánh dấu mã hàng hóa không hợp lệ bằng cách tạo một quy tắc định dạng điều kiện đơn giản có công thức =$B2<>5
Hay, bạn có thể xác định mã hàng hóa không hợp lệ bằng cách lồng ghép công thức LEN ở trên vào hàm IF:
=IF(LEN(LEFT($A2, SEARCH("-", $A2) -1))<>5, "Invalid","")
Như được diễn giải trong ảnh chụp màn hình dưới đây, công thức xác định mã hàng hóa không hợp lệ một cách hoàn hảo dựa trên chiều dài chuỗi, và bạn thậm chí không cần một cột đếm ký tự riêng biệt:
Tương tự, bạn có thể sử dụng hàm LEN trong Excel để đếm số ký tự sau một ký tự cụ thể.
Ví dụ, trong một danh sách tên, có thể bạn muốn biết họ của một người có bao nhiêu ký tự. Công thức LEN sau đây sẽ giải quyết việc này:
=LEN(RIGHT(A2, LEN(A2) -SEARCH(" ",A2)))
Công thức hoạt động như thế nào:
- Đầu tiên, bạn xác định vị trí của khoảng trống " " trong chuỗi ký tự bằng cách sử dụng hàm SEARCH: SEARCH(" ",A2)))
- Sau đó, bạn đếm có bao nhiêu ký tự phía sau khoảng trống. Về việc này, bạn lấy tổng chiều dài chuỗi trừ đi vị trí khoảng trống:
- LEN(A2) -SEARCH(" ", A2)))
- Sau đó, bạn sử dụng hàm RIGHT để trả về tất cả ký tự phía sau khoảng trống.
- Và cuối cùng, bạn sử dụng hàm LEN để tính chiều dài chuỗi được trả về bởi hàm RIGHT.
Xin hãy lưu ý rằng, để công thức hoạt động một cách chính xác, mỗi ô nên có chỉ một khoảng trống, ví dụ chỉ có tên và họ, không có tên lót, danh hiệu hay hậu tố.
Trên đây là toàn bộ cách dùng hàm LEN trong Excel cũng như ví dụ minh họa cụ thể. Hi vọng bài viết này giúp ích được cho các bạn. Chúc các bạn học tốt
